extends Node2D

const SURFACE_PROFILES = preload("res://PlanetSurfaceProfiles.gd")
const PLANET_DEFINITIONS = preload("res://PlanetDefinitions.gd")

# Bootstraps the surviving fleet, including each vessel type, on this scene's
# own startup (from GameState, since this is a fresh scene tree - nothing here
# carries over automatically) and handles the always-available exit prompt that
# fades back out to Main.tscn, restoring the fleet at wherever it left
# space from.

@export var fade_duration: float = 0.4

@onready var fleet: Node2D = get_node("../Fleet")
@onready var camera: Camera2D = get_node("../Camera2D")
@onready var planet_name_label: Label = get_node("../UI/PlanetNameLabel")
@onready var exit_button: IconButton = get_node("../UI/ExitButton")
@onready var fade_rect: ColorRect = get_node("../FadeOverlay/FadeRect")
@onready var background: ColorRect = get_node("../BackgroundLayer/LunarBackground")
@onready var feature_host: Node2D = get_node("../SurfaceFeatures")

var transitioning: bool = false


func _ready() -> void:
	var planet_definition: Resource = PLANET_DEFINITIONS.get_definition(GameState.planet_definition_id)
	_compose_surface(SURFACE_PROFILES.get_profile(planet_definition.surface_profile_id))
	fleet.spawn_ships(GameState.surviving_ship_count, Vector2.ZERO,
		GameState.surviving_vessel_types)
	camera.position = Vector2.ZERO
	camera.zoom = Vector2(GameState.return_camera_zoom, GameState.return_camera_zoom)
	planet_name_label.text = GameState.planet_name
	exit_button.pressed.connect(_on_exit_pressed)

	fade_rect.color.a = 1.0
	var tween: Tween = create_tween()
	tween.tween_property(fade_rect, "color:a", 0.0, fade_duration)


func _compose_surface(profile: Resource) -> void:
	var atmosphere: ShaderMaterial = background.material
	atmosphere.set_shader_parameter("base_color", profile.base_color)
	atmosphere.set_shader_parameter("crater_color", profile.crater_color)
	atmosphere.set_shader_parameter("highlight_color", profile.highlight_color)
	for caption_path in ["../UI/BankCaption", "../UI/FleetCaption"]:
		var caption: Label = get_node(caption_path)
		caption.add_theme_color_override("font_color", profile.caption_color)
		caption.add_theme_color_override("font_outline_color", profile.caption_outline_color)
	if profile.features_scene == null:
		return
	var features: Node = profile.features_scene.instantiate()
	feature_host.add_child(features)


func _on_exit_pressed() -> void:
	if transitioning:
		return
	transitioning = true

	GameState.surviving_ship_count = fleet.ships.size()
	GameState.surviving_vessel_types = fleet.vessel_types()

	var tween: Tween = create_tween()
	tween.tween_property(fade_rect, "color:a", 1.0, fade_duration)
	tween.tween_callback(_return_to_space)


func _return_to_space() -> void:
	get_tree().change_scene_to_file("res://Main.tscn")