class_name EnemyPursuitComponent
extends Node

# Chases the nearest player ship. Moved out of Enemy.gd verbatim so the
# behaviour is opt-in per definition rather than hardcoded into every enemy.

var capability_id: String = "pursuit"
var velocity: Vector2 = Vector2.ZERO

# #69: used to beeline from anywhere on the map the instant it spawned,
# which read as omniscient rather than alert. Idle until the fleet actually
# comes within this radius. A persistent stalking threat wants the opposite
# of this - see EnemyPursuitComponentMothership.tscn, which overrides it to
# an effectively unlimited value for the mothership's own instance.
@export var detection_range: float = 850.0


func tick(delta: float) -> void:
	var enemy: Node2D = get_parent()
	var target: Node2D = _nearest_ship(enemy)
	if target == null or enemy.position.distance_to(target.position) > detection_range:
		return
	var to_target: Vector2 = target.position - enemy.position

	if to_target.length() > 1.0:
		var desired_velocity: Vector2 = to_target.normalized() * enemy.speed
		velocity = velocity.move_toward(desired_velocity, enemy.acceleration * delta)
		enemy.position += velocity * delta

	if velocity.length() > 5.0:
		var target_angle: float = velocity.angle() + PI / 2.0
		enemy.rotation = lerp_angle(enemy.rotation, target_angle, enemy.rotation_speed * delta)


func _nearest_ship(enemy: Node2D) -> Node2D:
	var fleet: Node2D = get_tree().get_first_node_in_group("player_fleet")
	if fleet == null or fleet.ships.is_empty():
		return null

	var nearest: Node2D = fleet.ships[0]
	var best_dist: float = enemy.position.distance_to(nearest.position)
	for ship in fleet.ships:
		var d: float = enemy.position.distance_to(ship.position)
		if d < best_dist:
			best_dist = d
			nearest = ship
	return nearest