extends Node2D

# Draws each extractor's hauler ONLY while it is somewhere the player could
# see it, and rebuilds it from GameState every frame.
#
# The point is that the visuals are optional. GameState simulates the round
# trip and pays out on arrival regardless of what exists in the scene, so a
# route far from the player costs nothing but still earns - while flying
# between a planet and the mothership shows the hauler making the run,
# positioned from the very same `progress` value that triggers the payout.

@export var visible_radius: float = 2600.0

@onready var fleet: Node2D = get_node("../Fleet")

var hauler_scene: PackedScene = preload("res://logistics/Hauler.tscn")
# extractor index -> live Hauler node
var active: Dictionary = {}


func _process(_delta: float) -> void:
	var centre: Vector2 = fleet.get_centroid()

	for i in range(GameState.extractors.size()):
		var extractor: Dictionary = GameState.extractors[i]
		var pos: Variant = GameState.get_hauler_position(extractor)

		# No mothership means no route, so nothing to show.
		if pos == null or pos.distance_to(centre) > visible_radius:
			_despawn(i)
			continue

		var hauler: Node2D = active.get(i)
		if hauler == null or not is_instance_valid(hauler):
			hauler = hauler_scene.instantiate()
			get_parent().add_child(hauler)
			active[i] = hauler

		var previous: Vector2 = hauler.position
		hauler.position = pos
		# Laden on the outbound leg, empty on the way back.
		hauler.set_laden(extractor.progress <= GameState.HAULER_ARRIVAL)
		var travel: Vector2 = pos - previous
		if travel.length() > 0.5:
			hauler.rotation = travel.angle() + PI / 2.0

	# Drop visuals for extractors that no longer exist.
	for key in active.keys():
		if key >= GameState.extractors.size():
			_despawn(key)


func _despawn(index: int) -> void:
	var hauler: Node2D = active.get(index)
	if hauler != null and is_instance_valid(hauler):
		hauler.queue_free()
	active.erase(index)