spaceship/buildings/Building.gd

extends Node2D

const BUILDING_DEFINITIONS = preload("res://buildings/BuildingDefinitions.gd")

@export var definition_id: String = "mothership"
@export var building_id: int = 0
@export var interact_radius: float = 150.0

var definition: Resource
var visual: Node2D

var building_type: String:
	get: return definition_id
	set(value): definition_id = value


func _ready() -> void:
	add_to_group("buildings")
	z_index = -1
	definition = BUILDING_DEFINITIONS.get_definition(definition_id)
	if definition == null or definition.visual_scene == null:
		return
	visual = definition.visual_scene.instantiate()
	get_node("VisualHost").add_child(visual)


func available_actions() -> PackedStringArray:
	if visual == null:
		return PackedStringArray()
	var provider: Node = visual.get_node_or_null("ActionProvider")
	return provider.actions if provider != null else PackedStringArray()


func primary_action() -> String:
	for action in available_actions():
		if action != "transfer" and action != "hangar":
			return action
	return ""


func get_display_name() -> String:
	return String(definition.display_name) if definition != null else definition_id.capitalize()